Новые индикаторы

Индикаторы, написанные участниками форума. Делимся своими наработками.
Ответить
Сообщение
Автор
Аватара пользователя
Terranin
Site Admin
Сообщения: 846
Зарегистрирован: Вс июл 23, 2006 12:01 pm

Новые индикаторы

#1 Сообщение Terranin » Чт окт 26, 2006 5:05 pm

Выкладываю новые индикаторы которые будут включены в следующий билд.

Polarized Fractal Efficiency
Ultimate oscillator
Demark's Range Expansion Index
Pivot Points
Вложения
Indicators.zip
(206.86 КБ) 1850 скачиваний
Asta la vista
Mike

mr.Rich
Сообщения: 21
Зарегистрирован: Сб дек 09, 2006 12:56 pm

#2 Сообщение mr.Rich » Чт дек 14, 2006 1:59 pm

Всем привет.
А где можно взять индикатор параболик Par. SAR?
Если его нет, тогда планирутеся ли сделать его?
И на чем пишутся индикаторы, на делфи ?

Аватара пользователя
Terranin
Site Admin
Сообщения: 846
Зарегистрирован: Вс июл 23, 2006 12:01 pm

#3 Сообщение Terranin » Чт дек 14, 2006 4:57 pm

mr.Rich писал(а):Всем привет.
А где можно взять индикатор параболик Par. SAR?
Если его нет, тогда планирутеся ли сделать его?
И на чем пишутся индикаторы, на делфи ?
Параболик пока не готов но планируется. Индикаторы пишутся пока на Дельфи, потом планируется выпуск апи на С++.
Asta la vista
Mike

mr.Rich
Сообщения: 21
Зарегистрирован: Сб дек 09, 2006 12:56 pm

#4 Сообщение mr.Rich » Чт дек 14, 2006 9:45 pm

А где можно найти Акселератор дедушки Вильямса тодько для МТ.
(такой же как FT, в MT другой немного. Ежели у вас есть, поделитесь?
И можно ли сделать так чтобы поступали реальные данные в реальном времени? например от альпари или от другого какого-нибудб дил. центра?

Аватара пользователя
Terranin
Site Admin
Сообщения: 846
Зарегистрирован: Вс июл 23, 2006 12:01 pm

#5 Сообщение Terranin » Пт дек 15, 2006 7:58 am

mr.Rich писал(а):А где можно найти Акселератор дедушки Вильямса тодько для МТ.
(такой же как FT, в MT другой немного. Ежели у вас есть, поделитесь?
И можно ли сделать так чтобы поступали реальные данные в реальном времени? например от альпари или от другого какого-нибудб дил. центра?
Насчет акселератора не знаю. Данные когда-нибудь начнут поступать. Со временем.
Asta la vista
Mike

Pete
Сообщения: 3
Зарегистрирован: Пт янв 05, 2007 8:02 pm

#6 Сообщение Pete » Пт янв 05, 2007 8:19 pm

С Новым годом!
Скажите, а если есть dll и текст индикатора на нескольких языках, его можно прикрутить? поможете?
Я про фильтр Ходрика-Прескотта. Тексты программ по крайней мере в 10 форматах есть в открытом доступе.
Спасибо.

deguar
Сообщения: 2
Зарегистрирован: Вс май 27, 2007 5:57 pm

#7 Сообщение deguar » Вс май 27, 2007 6:02 pm

Теранин в ключи план индикаторо. Индикатор Мюрея.

Как только ты его включиш я сразу же куплю твою прогу.

И воздвигну памтник из бронзы!

вот правильный код в mql4. В сети их масса но очень много не правильных.

Код: Выделить всё

//+------------------------------------------------------------------+
//|                                            Murrey_Math_Lines.mq4 |
//|                         Copyright © 2004, Vladislav Goshkov (VG).|
//|                                                      4vg@mail.ru |
//|                      code change by Ben L.  sbgtrading@yahoo.com |
//+------------------------------------------------------------------+
#property copyright "Vladislav Goshkov (VG) && Ben L."
#property link      "4vg@mail.ru && sbgtrading@yahoo.com"

#property indicator_chart_window

// ============================================================================================
// * Line 8/8 & 0/8 (Ultimate Support and Ultimate Resistance).
// * Those lines are the most strong concerning Support and esistance.
// ============================================================================================
//* Line 7/8  (Weak, Place to Stop and Reverse).
//* This line is weak. If suddenly the price was going too fast and too far and stops around this line 
//* it means the price will reverse down very soon. If the price did not stop near this line this price 
//* will continue the movement to the line 8/8.
// ============================================================================================
//* Line 1/8  (Weak, Place to Stop and Reverse).
//* This line is weak. If suddenly the price was going too fast and too far and stops around this line 
//* it means the price will reverse up very soon. If the price did not stop near this line this price
//* will continue the movement down to the line 0/8.
// ============================================================================================
//* Line 2/8 and 6/8 (Pivot, Reverse)
//* Those two lines yield the line 4/8 only to the strength to reverse the price movement.
// ============================================================================================
//* Line 5/8 (Top of Trading Range)
//* The price is spending the about 40% of the time on the movement between the lines 5/8 and 3/8. 
//* If the price is moving near line 5/8 and stopping near the line during the 10 - 12 days so it means 
//* that it is necessary to sell in this "bonus zone" (some people are doing like this) but if the price is keeping the tendency to stay above 
//* 5/8 line, so it means that the price will be above. But if the price is droping below 5/8 line it means that the price will continue 
//* falling to the next level of resistance.
// ============================================================================================
//* Line 3/8 (Bottom of Trading Range).
//* If the price is below this line and in uptrend it means that it will be very difficult for the price to break this level. 
//* If the price broke this line during the uptrend and staying above during the 10 12 days it means that the price will be above this line 
//* during the 40% of its time moving between this line and 5/8 line.
// ============================================================================================
//* Line 4/8 (Major Support/Resistance Line).
//* It is the major line concerning support and resistance. This leve is the better for the new sell or buy. 
//* It is the strong level of support of the price is above 4/8. It is the fine resistance line if the price is below this 4/8 line. 
// ============================================================================================
extern int P = 64;
extern int StepBack = 0;

extern color  mml_clr_m_2_8 = White;       // [-2]/8
extern color  mml_clr_m_1_8 = White;       // [-1]/8
extern color  mml_clr_0_8   = Aqua;        //  [0]/8
extern color  mml_clr_1_8   = Yellow;      //  [1]/8
extern color  mml_clr_2_8   = Red;         //  [2]/8
extern color  mml_clr_3_8   = MediumSeaGreen;       //  [3]/8
extern color  mml_clr_4_8   = Blue;        //  [4]/8
extern color  mml_clr_5_8   = MediumSeaGreen;       //  [5]/8
extern color  mml_clr_6_8   = Red;         //  [6]/8
extern color  mml_clr_7_8   = Yellow;      //  [7]/8
extern color  mml_clr_8_8   = Aqua;        //  [8]/8
extern color  mml_clr_p_1_8 = White;       // [+1]/8
extern color  mml_clr_p_2_8 = White;       // [+2]/8

extern int    mml_wdth_m_2_8 = 2;        // [-2]/8
extern int    mml_wdth_m_1_8 = 2;        // [-1]/8
extern int    mml_wdth_0_8   = 2;        //  [0]/8
extern int    mml_wdth_1_8   = 2;        //  [1]/8
extern int    mml_wdth_2_8   = 2;        //  [2]/8
extern int    mml_wdth_3_8   = 2;        //  [3]/8
extern int    mml_wdth_4_8   = 2;        //  [4]/8
extern int    mml_wdth_5_8   = 2;        //  [5]/8
extern int    mml_wdth_6_8   = 2;        //  [6]/8
extern int    mml_wdth_7_8   = 2;        //  [7]/8
extern int    mml_wdth_8_8   = 2;        //  [8]/8
extern int    mml_wdth_p_1_8 = 2;        // [+1]/8
extern int    mml_wdth_p_2_8 = 2;        // [+2]/8

extern color  MarkColor   = Blue;
extern int    MarkNumber  = 217;


double  dmml = 0,
        dvtl = 0,
        sum  = 0,
        PeriodLow = 0,
        PeriodHigh = 0,
        mn = 0,
        mx = 0,
        x1 = 0,
        x2 = 0,
        x3 = 0,
        x4 = 0,
        x5 = 0,
        x6 = 0,
        y1 = 0,
        y2 = 0,
        y3 = 0,
        y4 = 0,
        y5 = 0,
        y6 = 0,
        octave = 0,
        fractal = 0,
        range   = 0,
        finalH  = 0,
        finalL  = 0,
        mml[13];

string  ln_txt[13],        
        buff_str = "";
        
int     
        bnLow   = 0,
        bnHigh   = 0,
        OctLinesCnt = 13,
        mml_clr[13],
        mml_wdth[13],
        mml_shft = 40,
        nTime = 0,
        CurPeriod = 0,
        i = 0;

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init() {
//---- indicators
   
   ln_txt[0]  = "[-2/8]BUY! (Extremly Oversold)";// "extremely overshoot [-2/8]";// [-2/8]
   ln_txt[1]  = "[-1/8]buy (Oversold)";// "overshoot [-1/8]";// [-1/8]
   ln_txt[2]  = "[0/8]Ultimate support";// "Ultimate Support - extremely oversold [0/8]";// [0/8]
   ln_txt[3]  = "[1/8]Weak sup (stop and Reverse)";// "Weak, Place to Stop and Reverse - [1/8]";// [1/8]
   ln_txt[4]  = "[2/8]Pivot buy (Reverse)";// "Pivot, Reverse - major [2/8]";// [2/8]
   ln_txt[5]  = "[3/8]RangeBot of trading Range";// "Bottom of Trading Range - [3/8], if 10-12 bars then 40% Time. BUY Premium Zone";//[3/8]
   ln_txt[6]  = "[4/8]Center (Good Buy or Sell)";// "Major Support/Resistance Pivotal Point [4/8]- Best New BUY or SELL level";// [4/8]
   ln_txt[7]  = "[5/8]RangeTop ";// "Top of Trading Range - [5/8], if 10-12 bars then 40% Time. SELL Premium Zone";//[5/8]
   ln_txt[8]  = "[6/8]Pivot sell (Major Reverse)";// "Pivot, Reverse - major [6/8]";// [6/8]
   ln_txt[9]  = "[7/8]Weak res (Stop and Reverse)";// "Weak, Place to Stop and Reverse - [7/8]";// [7/8]
   ln_txt[10] = "[8/8]Ultimate resistance";// "Ultimate Resistance - extremely overbought [8/8]";// [8/8]
   ln_txt[11] = "[+1/8]sell (Overbought)";// "overshoot [+1/8]";// [+1/8]
   ln_txt[12] = "[+2/8]SELL! (extremely overbought)";// "extremely overshoot [+2/8]";// [+2/8]


   mml_clr[0]  = mml_clr_m_2_8;   mml_wdth[0] = mml_wdth_m_2_8; // [-2]/8
   mml_clr[1]  = mml_clr_m_1_8;   mml_wdth[1] = mml_wdth_m_1_8; // [-1]/8
   mml_clr[2]  = mml_clr_0_8;     mml_wdth[2] = mml_wdth_0_8;   //  [0]/8
   mml_clr[3]  = mml_clr_1_8;     mml_wdth[3] = mml_wdth_1_8;   //  [1]/8
   mml_clr[4]  = mml_clr_2_8;     mml_wdth[4] = mml_wdth_2_8;   //  [2]/8
   mml_clr[5]  = mml_clr_3_8;     mml_wdth[5] = mml_wdth_3_8;   //  [3]/8
   mml_clr[6]  = mml_clr_4_8;     mml_wdth[6] = mml_wdth_4_8;   //  [4]/8
   mml_clr[7]  = mml_clr_5_8;     mml_wdth[7] = mml_wdth_5_8;   //  [5]/8
   mml_clr[8]  = mml_clr_6_8;     mml_wdth[8] = mml_wdth_6_8;   //  [6]/8
   mml_clr[9]  = mml_clr_7_8;     mml_wdth[9] = mml_wdth_7_8;   //  [7]/8
   mml_clr[10] = mml_clr_8_8;     mml_wdth[10]= mml_wdth_8_8;   //  [8]/8
   mml_clr[11] = mml_clr_p_1_8;   mml_wdth[11]= mml_wdth_p_1_8; // [+1]/8
   mml_clr[12] = mml_clr_p_2_8;   mml_wdth[12]= mml_wdth_p_2_8; // [+2]/8
   
   for( i=0; i<OctLinesCnt; i++) {
         mml[i] = 0;
      }
   
//----
   return(0);
  }

//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit() {
//---- 
Comment(" ");
for(i=0;i<OctLinesCnt;i++) {
    buff_str = "mml"+i;
    ObjectDelete(buff_str);
    buff_str = "mml_txt"+i;
    ObjectDelete(buff_str);
    }
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start() {

//---- 

if((nTime != Time[0]) || (CurPeriod != Period())) {
   
  //price
   bnLow = Lowest(NULL,PERIOD_D1,MODE_LOW,P,StepBack);
   bnHigh = Highest(NULL,PERIOD_D1,MODE_HIGH,P,StepBack);

   PeriodLow = iLow(NULL,PERIOD_D1,bnLow);
   PeriodHigh = iHigh(NULL,PERIOD_D1,bnHigh);
   Comment("Murrey Math ",DoubleToStr(P,0), " day frame");

//determine fractal.....
   if( PeriodHigh<=250000 && PeriodHigh>25000 )
   fractal=100000;
   else
     if( PeriodHigh<=25000 && PeriodHigh>2500 )
     fractal=10000;
     else
       if( PeriodHigh<=2500 && PeriodHigh>250 )
       fractal=1000;
       else
         if( PeriodHigh<=250 && PeriodHigh>25 )
         fractal=100;
         else
           if( PeriodHigh<=25 && PeriodHigh>12.5 )
           fractal=12.5;
           else
             if( PeriodHigh<=12.5 && PeriodHigh>6.25)
             fractal=12.5;
             else
               if( PeriodHigh<=6.25 && PeriodHigh>3.125 )
               fractal=6.25;
               else
                 if( PeriodHigh<=3.125 && PeriodHigh>1.5625 )
                 fractal=3.125;
                 else
                   if( PeriodHigh<=1.5625 && PeriodHigh>0.390625 )
                   fractal=1.5625;
                   else
                     if( PeriodHigh<=0.390625 && PeriodHigh>0)
                     fractal=0.1953125;
   
   range=(PeriodHigh-PeriodLow);
   sum=MathFloor(MathLog(fractal/range)/MathLog(2));
   octave=fractal*(MathPow(0.5,sum));
   mn=MathFloor(PeriodLow/octave)*octave;
   if( (mn+octave)>PeriodHigh )
      mx=mn+octave; 
   else
      mx=mn+(2*octave);

// calculating xx
//x2
    if( (PeriodLow>=(3*(mx-mn)/16+mn)) && (PeriodHigh<=(9*(mx-mn)/16+mn)) )
         x2=mn+(mx-mn)/2; 
    else x2=0;
//x1
    if( (PeriodLow>=(mn-(mx-mn)/8))&& (PeriodHigh<=(5*(mx-mn)/8+mn)) && (x2==0) )
         x1=mn+(mx-mn)/2; 
    else x1=0;

//x4
    if( (PeriodLow>=(mn+7*(mx-mn)/16))&& (PeriodHigh<=(13*(mx-mn)/16+mn)) )
         x4=mn+3*(mx-mn)/4; 
    else x4=0;

//x5
    if( (PeriodLow>=(mn+3*(mx-mn)/8))&& (PeriodHigh<=(9*(mx-mn)/8+mn))&& (x4==0) )
         x5=mx; 
    else x5=0;

//x3
    if( (PeriodLow>=(mn+(mx-mn)/8))&& (PeriodHigh<=(7*(mx-mn)/8+mn))&& (x1==0) && (x2==0) && (x4==0) && (x5==0) )
         x3=mn+3*(mx-mn)/4; 
    else x3=0;

//x6
    if( (x1+x2+x3+x4+x5) ==0 )
         x6=mx; 
    else x6=0;

     finalH = x1+x2+x3+x4+x5+x6;

// calculating yy
//y1
    if( x1>0 )
         y1=mn; 
    else y1=0;

//y2
    if( x2>0 )
         y2=mn+(mx-mn)/4; 
    else y2=0;

//y3
    if( x3>0 )
         y3=mn+(mx-mn)/4; 
    else y3=0;

//y4
    if( x4>0 )
         y4=mn+(mx-mn)/2; 
    else y4=0;

//y5
    if( x5>0 )
         y5=mn+(mx-mn)/2; 
    else y5=0;

//y6
    if( (finalH>0) && ((y1+y2+y3+y4+y5)==0) )
         y6=mn; 
    else y6=0;

    finalL = y1+y2+y3+y4+y5+y6;

   dmml = (finalH-finalL)/8;


   mml[0]=(finalL-dmml*2); //-2/8
   for( i=1; i<OctLinesCnt; i++) {
        mml[i] = mml[i-1] + dmml;
        }
   for( i=0; i<OctLinesCnt; i++ ){
        buff_str = "mml"+i;
        if(ObjectFind(buff_str) == -1) {
           ObjectCreate(buff_str, OBJ_HLINE , 0,Time[0], mml[i]);
           ObjectSet(buff_str, OBJPROP_STYLE, STYLE_SOLID);
           ObjectSet(buff_str, OBJPROP_COLOR, mml_clr[i]);
           ObjectSet(buff_str, OBJPROP_WIDTH, mml_wdth[i]);
       ObjectMove(buff_str, 0, Time[0],  mml[i]);
           }
        else {
      ObjectMove(buff_str, 0, Time[0],  mml[i]);
           }
             
        buff_str = "mml_txt"+i;
        if(ObjectFind(buff_str) == -1) {
           ObjectCreate(buff_str, OBJ_TEXT, 0, Time[mml_shft], mml_shft);
           ObjectSetText(buff_str, ln_txt[i], 10, "Arial", mml_clr[i]);
           ObjectMove(buff_str, 0, Time[mml_shft],  mml[i]);
           }
        else {
           ObjectMove(buff_str, 0, Time[mml_shft],  mml[i]);
           }
        } // for( i=1; i<=OctLinesCnt; i++ ){

   nTime    = Time[0];
   CurPeriod= Period();
   
   }
 
//---- End Of Program
  return(0);
  }
//+------------------------------------------------------------------+

Аватара пользователя
Terranin
Site Admin
Сообщения: 846
Зарегистрирован: Вс июл 23, 2006 12:01 pm

#8 Сообщение Terranin » Вс май 27, 2007 6:39 pm

За такой индикатор точно памятник ставить надо... Я не занимаюсь индикаторами лично, я ядро программы развиваю и техническую поддержку обеспечиваю. Ищите единомышленников на форуме или есть за деньги люди делают индикаторы.
Asta la vista
Mike

VVV
Сообщения: 13
Зарегистрирован: Сб дек 09, 2006 12:50 pm

Re: Новые индикаторы

#9 Сообщение VVV » Чт июн 28, 2007 2:16 pm

Terranin писал(а):Выкладываю новые индикаторы которые будут включены в следующий билд.

Polarized Fractal Efficiency
Ultimate oscillator
Demark's Range Expansion Index
Pivot Points
Добрый день, а не могли бы выложить исходник Demark's Range Expansion Index т.к. есть необходимость использовать данные этого индикаторв в другом индикаторе.

Аватара пользователя
Terranin
Site Admin
Сообщения: 846
Зарегистрирован: Вс июл 23, 2006 12:01 pm

Re: Новые индикаторы

#10 Сообщение Terranin » Чт июн 28, 2007 2:28 pm

VVV писал(а):
Terranin писал(а):Выкладываю новые индикаторы которые будут включены в следующий билд.

Polarized Fractal Efficiency
Ultimate oscillator
Demark's Range Expansion Index
Pivot Points
Добрый день, а не могли бы выложить исходник Demark's Range Expansion Index т.к. есть необходимость использовать данные этого индикаторв в другом индикаторе.
В секции скачивания на сайте лежат исходники всех индикаторов. Недавно обновил. Этот индикатор называется там TDREI.dpr.
Asta la vista
Mike

kazak-don
Сообщения: 1
Зарегистрирован: Чт фев 11, 2010 2:50 pm
Откуда: Сталинград
Контактная информация:

Индикаторы

#11 Сообщение kazak-don » Чт фев 11, 2010 4:38 pm

Позвольте с Вами не согласиться ув. deguar
Мне кажется данная работа. куда как более соответствуем действительности, нежели приведённая Вами, а главное менее топорно исполнена, и гораздо удобней в работе (хотя тоже не оригинал, но лучше из всего МТ4шного мусора я ещё не встречал):

//+------------------------------------------------------------------+
//| Ind-Murrey_Math_MT4_VG-1.mq4 |
//| Copyright © 2005, Kara Software Corp. |
//| |
//+------------------------------------------------------------------+
#property copyright "Vladislav Goshkov (VG)."
#property link "4vg@mail.ru"

#property indicator_chart_window
#property indicator_buffers 8
#property indicator_color1 DarkBlue
#property indicator_color2 Aqua
#property indicator_color3 DarkGreen
#property indicator_color4 Blue
#property indicator_color5 DarkGreen
#property indicator_color6 Red
#property indicator_color7 Aqua
#property indicator_color8 DarkBlue
//---- input parameters
extern int P = 64;
extern int StepBack = 0;
extern int Bar = 1000;
//---- buffers
double ExtMapBuffer1[];
double ExtMapBuffer2[];
double ExtMapBuffer3[];
double ExtMapBuffer4[];
double ExtMapBuffer5[];
double ExtMapBuffer6[];
double ExtMapBuffer7[];
double ExtMapBuffer8[];
//+------------------------------------------------------------------+
double dmml = 0,
dvtl = 0,
sum = 0,
v1 = 0,
v2 = 0,
mn = 0,
mx = 0,
x1 = 0,
x2 = 0,
x3 = 0,
x4 = 0,
x5 = 0,
x6 = 0,
y1 = 0,
y2 = 0,
y3 = 0,
y4 = 0,
y5 = 0,
y6 = 0,
octave = 0,
fractal = 0,
range = 0,
finalH = 0,
finalL = 0,
mml[13];

string ln_txt[13],
buff_str = "";

int
bn_v1 = 0,
bn_v2 = 0,
OctLinesCnt = 13,
mml_thk = 8,
mml_clr[13],
mml_shft = 3,
nTime = 0,
CurPeriod = 0,
nDigits = 0,
i = 0;
//------------------------------------------------------------------
int init()
{
//---- indicators
SetIndexStyle(0,DRAW_LINE);
SetIndexBuffer(0,ExtMapBuffer1);
SetIndexStyle(1,DRAW_LINE);
SetIndexBuffer(1,ExtMapBuffer2);
SetIndexStyle(2,DRAW_LINE);
SetIndexBuffer(2,ExtMapBuffer3);
SetIndexStyle(3,DRAW_LINE);
SetIndexBuffer(3,ExtMapBuffer4);
SetIndexStyle(4,DRAW_LINE);
SetIndexBuffer(4,ExtMapBuffer5);
SetIndexStyle(5,DRAW_LINE);
SetIndexBuffer(5,ExtMapBuffer6);
SetIndexStyle(6,DRAW_LINE);
SetIndexBuffer(6,ExtMapBuffer7);
SetIndexStyle(7,DRAW_LINE);
SetIndexBuffer(7,ExtMapBuffer8);
//---- indicators

ln_txt[0] = "[-2/8]P";// "extremely overshoot [-2/8]";// [-2/8]
ln_txt[1] = "[-1/8]P";// "overshoot [-1/8]";// [-1/8]
ln_txt[2] = "[0/8]P";// "Ultimate Support - extremely oversold [0/8]";// [0/8]
ln_txt[3] = "[1/8]P";// "Weak, Stall and Reverse - [1/8]";// [1/8]
ln_txt[4] = "[2/8]P";// "Pivot, Reverse - major [2/8]";// [2/8]
ln_txt[5] = "[3/8]P";// "Bottom of Trading Range - [3/8], if 10-12 bars then 40% Time. BUY Premium Zone";//[3/8]
ln_txt[6] = "[4/8]P";// "Major Support/Resistance Pivotal Point [4/8]- Best New BUY or SELL level";// [4/8]
ln_txt[7] = "[5/8]P";// "Top of Trading Range - [5/8], if 10-12 bars then 40% Time. SELL Premium Zone";//[5/8]
ln_txt[8] = "[6/8]P";// "Pivot, Reverse - major [6/8]";// [6/8]
ln_txt[9] = "[7/8]P";// "Weak, Stall and Reverse - [7/8]";// [7/8]
ln_txt[10] = "[8/8]P";// "Ultimate Resistance - extremely overbought [8/8]";// [8/8]
ln_txt[11] = "[+1/8]P";// "overshoot [+1/8]";// [+1/8]
ln_txt[12] = "[+2/8]P";// "extremely overshoot [+2/8]";// [+2/8]

mml_shft = 3;
mml_thk = 3;

// Начальная установка цветов уровней октав
mml_clr[0] = DarkBlue; // [-2]/8
mml_clr[1] = DarkViolet; // [-1]/8
mml_clr[2] = Aqua; // [0]/8
mml_clr[3] = Yellow; // [1]/8
mml_clr[4] = Red; // [2]/8
mml_clr[5] = DarkGreen; // [3]/8
mml_clr[6] = Blue; // [4]/8
mml_clr[7] = DarkGreen; // [5]/8
mml_clr[8] = Red; // [6]/8
mml_clr[9] = Yellow; // [7]/8
mml_clr[10] = Aqua; // [8]/8
mml_clr[11] = DarkViolet; // [+1]/8
mml_clr[12] = DarkBlue; // [+2]/8
//----
return(0);
}
int deinit() {
//---- TODO: add your code here
Comment(" ");
for(i=0;i<OctLinesCnt;i++) {
buff_str = "mml"+i;
ObjectDelete(buff_str);
buff_str = "mml_txt"+i;
ObjectDelete(buff_str);
}
//----
return(0);
}
//======================================================================
int MyFunc(int shift)
{
if( (nTime != Time[shift]) || (CurPeriod != Period()) ) {

//price
bn_v1 = Lowest(NULL,0,MODE_LOW,P+StepBack,shift);
bn_v2 = Highest(NULL,0,MODE_HIGH,P+StepBack,shift);

v1 = Low[bn_v1];
v2 = High[bn_v2];

//determine fractal.....
if( v2<=250000 && v2>25000 )
fractal=100000;
else
if( v2<=25000 && v2>2500 )
fractal=10000;
else
if( v2<=2500 && v2>250 )
fractal=1000;
else
if( v2<=250 && v2>25 )
fractal=100;
else
if( v2<=25 && v2>12.5 )
fractal=12.5;
else
if( v2<=12.5 && v2>6.25)
fractal=12.5;
else
if( v2<=6.25 && v2>3.125 )
fractal=6.25;
else
if( v2<=3.125 && v2>1.5625 )
fractal=3.125;
else
if( v2<=1.5625 && v2>0.390625 )
fractal=1.5625;
else
if( v2<=0.390625 && v2>0)
fractal=0.1953125;

range=(v2-v1);
sum=MathFloor(MathLog(fractal/range)/MathLog(2));
octave=fractal*(MathPow(0.5,sum));
mn=MathFloor(v1/octave)*octave;
if( (mn+octave)>v2 )
mx=mn+octave;
else
mx=mn+(2*octave);


// calculating xx
//x2
if( (v1>=(3*(mx-mn)/16+mn)) && (v2<=(9*(mx-mn)/16+mn)) )
x2=mn+(mx-mn)/2;
else x2=0;
//x1
if( (v1>=(mn-(mx-mn)/8))&& (v2<=(5*(mx-mn)/8+mn)) && (x2==0) )
x1=mn+(mx-mn)/2;
else x1=0;

//x4
if( (v1>=(mn+7*(mx-mn)/16))&& (v2<=(13*(mx-mn)/16+mn)) )
x4=mn+3*(mx-mn)/4;
else x4=0;

//x5
if( (v1>=(mn+3*(mx-mn)/8))&& (v2<=(9*(mx-mn)/8+mn))&& (x4==0) )
x5=mx;
else x5=0;

//x3
if( (v1>=(mn+(mx-mn)/8))&& (v2<=(7*(mx-mn)/8+mn))&& (x1==0) && (x2==0) && (x4==0) && (x5==0) )
x3=mn+3*(mx-mn)/4;
else x3=0;

//x6
if( (x1+x2+x3+x4+x5) ==0 )
x6=mx;
else x6=0;

finalH = x1+x2+x3+x4+x5+x6;
// calculating yy
//y1
if( x1>0 )
y1=mn;
else y1=0;

//y2
if( x2>0 )
y2=mn+(mx-mn)/4;
else y2=0;

//y3
if( x3>0 )
y3=mn+(mx-mn)/4;
else y3=0;

//y4
if( x4>0 )
y4=mn+(mx-mn)/2;
else y4=0;

//y5
if( x5>0 )
y5=mn+(mx-mn)/2;
else y5=0;

//y6
if( (finalH>0) && ((y1+y2+y3+y4+y5)==0) )
y6=mn;
else y6=0;

finalL = y1+y2+y3+y4+y5+y6;

for( i=0; i<OctLinesCnt; i++) {
mml = 0;
}

dmml = (finalH-finalL)/8;

mml[0] =(finalL-dmml*2); //-2/8
for( i=1; i<OctLinesCnt; i++) {
mml = mml[i-1] + dmml;
}
for( i=0; i<OctLinesCnt; i++ ){
buff_str = "mml"+i;
if(i==0)ExtMapBuffer1[shift]=mml;
if(i==2)ExtMapBuffer2[shift]=mml;
if(i==5)ExtMapBuffer3[shift]=mml;
if(i==6)ExtMapBuffer4[shift]=mml;
if(i==7)ExtMapBuffer5[shift]=mml;
if(i==8)ExtMapBuffer6[shift]=mml;
if(i==10)ExtMapBuffer7[shift]=mml;
if(i==12)ExtMapBuffer8[shift]=mml;
// if(ObjectFind(buff_str) == -1) {
// ObjectCreate(buff_str, OBJ_HLINE, 0, Time[shift], mml[i]);
// ObjectSet(buff_str, OBJPROP_STYLE, STYLE_SOLID);
// ObjectSet(buff_str, OBJPROP_COLOR, mml_clr[i]);
// ObjectMove(buff_str, 0, Time[shift], mml[i]);
// }
// else {
// ObjectMove(buff_str, 0, Time[shift], mml[i]);
// }

buff_str = "mml_txt"+i;
if(ObjectFind(buff_str) == -1) {
ObjectCreate(buff_str, OBJ_TEXT, 0, Time[mml_shft], mml_shft);
ObjectSetText(buff_str, ln_txt[i], 8, "Arial", mml_clr[i]);
ObjectMove(buff_str, 0, Time[mml_shft], mml[i]);
}
else {
ObjectMove(buff_str, 0, Time[mml_shft], mml[i]);
}
} // for( i=1; i<=OctLinesCnt; i++ ){

nTime = Time[shift];
CurPeriod= Period();

}

}
//------------------------------------------------------------------------
int start() {

//---- TODO: add your code here

for(int i=Bar;i>=0;i--)
{
MyFunc(i);
}

//---- End Of Program
return(0);
}
//+------------------------------------------------------------------+

Ответить